Barco TransForm A User Manual page 137

The switcher definition language in the BNF notation
In the following the switcher definition language is declared in the BNF (Backus Naur Form):
alpha ::= 'a' .. 'z' | 'A' .. 'Z' | '-' | '!' | '_'
digit ::= '0' .. '9'
name ::= alpha {alpha | digit}
dev_name ::= name | ('"' name '"')
string ::= name | ('"' {any} '"')
number ::= digit {digit}
eq ::= '='
bits ::= '4' .. '8'
parity ::= 'n' | 'e' | 'o'
stopbits ::= '1' | '1.5' | '2'
file_name ::= name ['.' name]
sw_types ::= dev_name
frg_types ::= dev_name
sw_name ::= dev_name
cmp_name ::== string
sw_dev ::= sw_type '[' number ']' ['[' number ']']
listname ::= string
sourcename ::= string
dfrg_name ::= dev_name
frg_name ::= dev_name
frg_dev ::= [cmp_name':'] frg_type '[' number ']'
sw_output ::= (sw_name | sw_dev) '.' number
sw_input ::= sw_output
frg_input ::= (frg_name | frg_dev) '.' number
file ::= {section}
section ::= include | switcher | computer | grabber | dfrg | sourcelist | routes | cables
include ::= 'include' file_name
switcher ::= 'switcher' sw_name '{' {sw_def} '}'
computer ::= 'computer' cmp_name '{' {cmp_def} '}'
grabber ::= 'grabber' frg_name '{' grabber_def '}'
dfrg ::= 'dfrg' dfrg_name '{' dfrg_def '}'
sourcelist ::= 'sourcelist' listname '{' source_def '}'
routes ::= 'routes' '{' {route_def} '}'
cables ::= 'cables' '{' {cable_def} '}'
sw_def ::= device | connection | baudrate | type | inputs | outputs | level | videotype |
host | port | remotetype
cmp_def ::= hostname | ipaddress
host ::= cmp_name
hostname ::= 'name' eq name';'
ipaddress ::= 'ipaddress' eq ip_def ';'
port ::= 'port' eq number
ipdef ::= digit[digit][digit].digit[digit][digit].digit[digit][digit].digit[digit][digit]
device ::= 'device' eq sw_dev ';'
connection ::= 'connection' eq name ';'
baudrate ::= 'baudrate' eq number ';'
type :== 'type' eq number
inputs ::= 'inputs' eq number ';'
outputs ::= 'outputs' eq number ';'
level ::= 'level' eq number ';'
videotype ::= 'videotype' eq vid_types ';'
grabber_def ::= 'device' eq frg_dev ';'
dfrg_def ::= (frg_name | frg_dev) {',' frg_name | frg_dev } ';'
source_def ::= source_descr {source_descr}
source_descr ::= sourcename ',' name [',' name] ';'
route_def ::= listname 'to' (frg_name | frg_dev | dfrg_name ){',' (frg_name | frg_dev |
dfrg_name)} ';'
cable_def ::= sourcename | sw_output 'to' sw_input | frg_input {',' sw_input | frg_input}';'
Barco – TransForm A - Workstation for Windows – DOC-3266-2 – Revision 13 – April 2006
6. Advanced configuration
_______________________________________________________________
6-17