Setra Systems Super Count Operator's Manual page 52

scale units to grams, e) set the ID to ABC-123, f) read the ID back from the scale and g) wait for a
stable reading and obtain a weight. This program will work with an IBM* PC type .computer using
BASIC A or GW BASIC version 3.0 or higher.
100 CLS
120 PRINT " Setra 404 SCALE COMMUNICATIONS TEST"
140 PRINT " PLEASE INPUT THE SCALE'S BAUD RATE .... USUALLY 2400"
160 INPUT BAUD$
180 PRINT" PLEASE INDICATE WHICH COMPUTER COM PORT YOU ARE USING (1 OR 2)";
200 INPUT I%
220 IF I%=2 THEN PORT$="COM2" ELSE PORT$="COM1"
240 REM: OPEN THE COMMUNICATIONS PORT & DISABLE ALL HANDSHAKES
260 REM: 8 DATA BITS WITH NO PARITY AND 1 STOP BIT IS SELECTED
280 O$=PORT$+":"+BAUD$+", N, 8, 1, RS, CS, DS,CD"
300 OPEN O$ FOR RANDOM AS #1
320 REM: VERIFY THE SCALE MODEL
340 REM: SCALE COMMANDS DO NOT USE A <CR> OR <LF>
360 REM: NOTE USE OF (;) AT END OF PRINT #1 STATEMENTS
380 PRINT #1, "V";
400 INPUT #1, A$
420 PRINT "SCALE MODEL IS: ";A$
500 LOCATE 7, 7: PRINT "PRESS 'Z' TO ZERO THE SCALE OR PRESS 'Q' TO QUIT"
520 REM: THIS COMMAND, '#' REQUESTS THE SCALE TO TRANSMIT DISPLAYED WEIGHT
540 PRINT #1, "#";
560 INPUT #1, A$
600 REM: THIS DISPLAYS THE WEIGHT TRANSMITTED BY THE SCALE
620 LOCATE 10, 10: PRINT "
640 LOCATE 10, 10: PRINT "THE WEIGHT ON THE SCALE IS: ";A$
699 REM: THIS CHECKS IF A COMMAND HAS BEEN REQUESTED VIA THE PC KEYBOARD
700 K$ = INKEY$
720 IF K$ = "" THEN GOTO 500
740 IF K$ = "Q" OR K$ = "q" THEN GOTO 1000
760 IF K$ = "Z" OR K$ = "z" THEN GOTO 800
780 GOTO 500
800 REM: THIS WILL ZERO THE SCALE
820 PRINT #1, "Z"
840 REM: THIS WILL REQUEST THE READING FROM THE SCALE COMMAND '#'
860 REM: THIS READING WILL NOT BE SENT UNTIL THE SCALE IS ZEROED
880 PRINT #1, "#";
900 INPUT #1, A$
920 GOTO 500
1000 REM: THIS IS THE END OF THE PROGRAM
* IBM is a registered trademark of International Business Machines, Inc.
52
COMMAND IS 'Z'
Setra Super Count
TM
Operator's Manual